Excel商务图表实战案例，教你用特殊符号打造高端图表！

通常我们要制作图表，都是在Excel中通过数据来生成图表。但是，今天所要给大家介绍的制作图表方法并非如此，它是利用一些特殊符号，然后通过函数完成对图表制作。这里我们会通过十个案例，详细的教大家制作方法！

  01 条形图

公式：

=REPT("|",B2)

REPT函数能够按照定义的次数重复显示定义的内容。

此时我们能够看到单元格中已经被竖线“|”填充满了，我们只需要更换一下字体颜色，条形图就算是完成了。如果你不喜欢默认竖线这种效果，可以将字体换成「Playbill」就变成实心的了。

  02 漏斗图

公式：

=REPT("|",B2/10)

漏斗图表在制作上是与条形图差不多的，只是多了一个居中对齐。在公式上我加了一个“/10”是因为默认情况下数据条太长影响效果，除以十会缩短一点。

  03 带负数的条形图

正数公式：

=IF(B2>0,REPT("|",B2),"")

负数公式：

=IF(B2<0,REPT("|",ABS(B2)),"")

ABS求绝对值函数，可将负数返回正数。

字体「Playbill」（当然你如果喜欢默认竖条风格就不用改了）。负数这边需要右对齐。

  04 甘特图

公式：

=REPT(" ",B2-MIN($B$2:$B$6))&REPT("|",(C2-B2))

REPT函数上面我们已经说过，能够按照定义的次数重复显示定义的内容。

这里的B2是计划开始日，减去MIN($B$2:$B$6)，MIN函数是返回的最小值，这里指的是返回“计划开始日”该列中最小的一个日期。这样就能获取时间差数，而这个差数会显示" "空格。

&连接符，连接后面的条形图。

  05 旋风对比图

公式：

=REPT("|",B2/5)

=REPT("|",C2/5)

字体「Playbill」，然后修改一下颜色。

  旋风对比图效果2

公式：

=B2&" "&REPT("|",B2/15)

=REPT("|",C2/15)&" "&C2

第二种风格的旋风图，有带数据，可能更加直观一点。直接用默认字体即可，修改一下颜色。公式中加了一个&连接符直接连接到数据单元格，空格作为分隔。

  06 柱形图

公式：

=REPT("|",C5)

向右填充，然后改字体，设置颜色。

此时，柱形图是横向的，我们选择这些柱形图，然后「右键」-「设置单元格格式」-「对齐」，在「方向」中设为「90」度。再点击「对齐方式」中的「底端对齐」和「居中」。

  07 人形图表

公式：

=REPT("웃",B2/4)

人形图表其实和条形图是一样的，只是将“|”竖线换成了“웃”人形符号。

  08 五星评分

公式：

=REPT("★",B2)&REPT("☆",(5-B2))

五星评分图表的制作，根据“综合评分”数据生成了★；&连接5-b2综合评分，得到剩下的数值，显示为☆。

  09 爱心评分

公式：

=REPT("♥",B2)&REPT("♡",(5-B2))

和上面的五星评分一样，只是替换了其中的特殊符号。

  10 百分比图表

公式：

=REPT("□",(1-C4)*100)&REPT("■",C4*100)

1、「右键」-「设置单元格格式」-「对齐」-「文本控制」-「自动换行」。拖动单元格宽度和高度，使其每一行只显示10个字符。（字体默认的等线）

2、美化一下，设置一下字体颜色和底色。

3、你也可以将正方形换成圆形，又是另一种效果。

=REPT("○",(1-G4)*100)&REPT("●",G4*100)

  提示说明：

1、不同字体会有不同效果，条形图、柱形图默认都是竖线“|”效果，实心效果可以切换为「Playbill」字体。大家可以多尝试一下，其他字体可能会有更佳的效果哟！

2、觉得图表太小，太细，可以将字号调大一点。

3、数据太长，导致图表很长，可以使用“/”除以2、除以5、除以10来缩小图表。如果数据太短想加长，则可以按照相反思路，“*”乘法。

4、特殊符号那么多，大家可以随意替换，多加灵活运用！